#
# interpun.sed
#
# -------------------------------------------------------------------------
# skrypt edytora strumieniowego sed 
# dokonuje automatycznej poprawy interpunkcji w plikach znakowych
#
# Copyleft: Jan Jełowicki, jasj@ozi.ar.wroc.pl, Wrocław 2001
# Rozpowszechnianie, używanie i rozbudowa mile widziane
# -------------------------------------------------------------------------
#
# usuń spacje po znakach otwierających
s/\([(\[{]\) *\([^ ]\)/\1\2/g
#
# wstaw jedną spację przed każdy znak otwierający
s/\([(\[{]\)/ \1/g
#
# wstaw jedną spację za zwykłe znaki interpunkcyjne i zamykające
s/\([,\.:;\?!)}]\)/\1 /g
# (z przyczyn technicznych znak "[" jest rozpatrywany osobno)
s/\(\]\)/\1 /g
#
# usuń spacje sprzed zwykłych znaków interpunkcyjnych i zamykających
s/ *\([!,\.:;\?)}]\)/\1/g
# (z przyczyn technicznych znak "]" jest rozpatrywany osobno)
s/ *\(\]\)/\1/g
#
# usuń spacje zza znaku separatora dziesiętnego
s/\([0-9]\)\([\.,]\) *\([0-9]\)/\1\2\3/g
#
# sklej ze sobą apostrofy symulujące cudzysłów podwójny, dodaj za nim spację
s/ *' *'/'' /g
#
# wstaw spacje przed przecinkami symulującymi cudzysłów podwójny 
s/,,/ ,,/g
#
# usuń spacje za przecinkami symulującymi cudzysłów podwójny 
s/,, */,,/g
#
# usuń spacje ze zbiegów zwykłych znaków interpunkcyjnych lub zamykających
s/\([!,\.:;\?'})]\) *\([!,\.:;\?)}]\)/\1\2/g
# (z przyczyn technicznych znak "]" jest rozpatrywany osobno)
s/\([!,\.:;\?'})]\) *\]/\1]/g
s/\] *\([!,\.:;\?)}]\)/]\1/g
s/\] *\]/]]/g
#
# usuń spacje ze zbiegów znaków otwierających 
s/\([({]\) *\([({,]\)/\1\2/g
# (z przyczyn technicznych znak "[" jest rozpatrywany osobno)
s/\[ *\([({]\)/[\1/g
s/\([({]\) *\[/\1[/g
s/\[ *\[/[[/g
#
# usuń spacje otaczające znak dzielenia
s/ *\([-\/]\) */\1/g
#
# otocz spacjami zespoły łączników symulujące myślniki 
s/\(-[-]+\)/ \1 /g
#
# każdą grupę spacji zastąp pojedynczą spacją 
s/  */ /g
#
# usuń spacje umieszczone na początku wiersza (znaki tabulacji pozostaną bez zmian)
s/^ //g
#